Moin Wolfgang,

das 1. Problem (Nachschlagefeld definieren führt zum Absturz) läßt sich 
umgehen, indem du die Tabellen-Defintion mit ObjectPal und restruct 
durchführst. Wenn du Hilfe brauchst, sag es kurz, der restruct Befehl 
hat so seine Tücken ...

zum 2. Problem:
Verantwortlich ist eine Pararox-Datei - ich weiß aber nicht mehr welche. 
Das Problem ist abeer in den newgroups öfter beschrieben.
Ich starte Parardox immer über eine Batch Datei s. Anhang (Tipp: pass 
die Variablen an).

Forhes Neues Jahr und schiet op ole Johr! :-)

Thies Grimm



Am 29.12.2021 um 09:26 schrieb Wolfgang Fieg:
> Beim Lauf von Paradox 5.0 unter Windows 10 auf einem 64-Bit-System treten
> zwei Probnleme auf:
> 
> 1. Der Versuch, zu einer Tabelle ein Nachschlagefeld zu definieren, führt
> zum Absturz des Programms.
> 
> 2. Trotz entsprechender Voreinstellung wird der letzte Desktop beim Neustart
> des Programms nicht wiederhergestellt.
> 
> Hat jemand ähnliche Probleme? Kann jemand helfen?
> 
> Wolfgang
> 
> 
> 
> 

startpdox1.cmd
:: clean start of Paradox

@Echo Off

:: **** Variables ****
Set Work=D:\Data\Work
Set Priv=D:\Data\Priv
Set IdapiCfg="C:\Program Files (x86)\Common Files\Borland Shared\BDE\IDAPI32.CFG"
SET NetDir=c:\Data
SET startScript="D:\Data\Work\frmFileBrowser.fsl"
SET pdox="C:\Program Files (x86)\Paradox\Programs\pdxwin32.exe"

ECHO.
ECHO *******************************************************************************
ECHO **** Variables                                                             ****
ECHO *******************************************************************************
ECHO Work        = %work%
ECHO Priv        = %Priv%
ECHO IdapiCfg    = %IdapiCfg%
ECHO NetDir      = %NetDir%
ECHO startScript = %startScript%
ECHO pdox        = %pdox%
ECHO *******************************************************************************
ECHO.

:: **** Registry ****

::  • Designer
reg add HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Designer /v GridSettings /d "cm 1 20" /f >NUL
reg add HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Designer /v RulerExtd /d on /f >NUL

::  • Editor Window
reg add "HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Editor Window" /v "Font name" /d Consolas /f >NUL
reg add "HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Editor Window" /v "Font size" /d 13 /f >NUL

::  • Properties
reg add HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Properties /v DeveloperMenu /d True /f >NUL
reg add HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Properties /v Level /d Advanced /f >NUL
reg add HKCU\Software\Corel\Paradox\11.0\PDOXWIN\Properties /v ShowStartupExpert /d False /f >NUL

::  • BDE LanguageDriver 
reg add "HKCU\Software\WOW6432Node\Borland\Database Engine\Settings\Drivers\Paradox\Init" /v LangDriver /d ANSII850 /f >NUL


:: **** create Dirs ****
if not exist %work%\NUL (md %work%)
if not exist %priv%\NUL (md %priv%)


:: **** delete lock files ****

::  • lck Files
if exist %work%\PARADOX.LCK (del %work%\PARADOX.LCK /F)
if exist %work%\PDOXUSRS.LCK (del %work%\PDOXUSRS.LCK /F) 
if exist %priv%\PARADOX.LCK (del %priv%\PARADOX.LCK /F) 
if exist %priv%\PDOXUSRS.LCK (del %priv%\PDOXUSRS.LCK /F) 

::  • tmp. files 
if exist %priv%\__*.* (del %priv%\__*.* /F) 

::  • xml files in priv
if exist %priv%\*.xml (del %priv%\*.xml /F) 

::  • NetDir
if exist %NetDir%\PDOXUSRS.NET (del %NetDir%\PDOXUSRS.NET /F) 

:: start Paradox
@Echo On
start "" %pdox% -w %work% -p %Priv% -o %IdapiCfg% -c -q %startScript%

exit

:: Paradox Commandline Options

:: -b Prevents multiple instances of Paradox from being loaded.
:: -c Starts Paradox with a clear desktop.
:: -d Filename Specifies an alternate PDOXWORK.INI
:: -e  Prevents writes to the system registry.
:: -f Forces writes to the system registry.
:: -i Filename Specifies an alternate PDOXWIN.INI file
:: -m Loads Paradox as a minimized application.
:: -n Prevents saving work and private directories on exit.
:: -o Filename Alternate BDE configuration file.
:: -p Directory Start with a different private directory
:: -q Suppresses the Paradox splash screen while it is loading.
:: -s Prevents resizing of the Paradox window.
:: -t Allows resizing of the Paradox window.
:: -w Directory Starts Paradox with the specified working directory.
:: -y Forces saving work and private directories on exit.
:: StartFile 

:: PDOXWORK.INI
:: folder definitions for use with the Project Viewer
:: By default, Paradox does not use an .INI file to store settings, but you can create a file named PDOXWORK.INI in your working directory, and Paradox will read settings from it automatically.

:: PDOXWIN.INI 
:: desktop settings. By default, Paradox does not use an .INI file to store settings, but you can create a file named PDOXWIN.INI and Paradox will read settings from it automatically.